@echo off
title CHUONG TRINH XOA VIRUS EXCEL

:: Kiem tra Admin
net session >nul 2>&1
if %errorLevel% neq 0 (
    echo Dang yeu cau chay che dong Administrator...
    powershell -Command "Start-Process '%~f0' -Verb RunAs"
    exit /b
)

setlocal EnableDelayedExpansion

set "TARGET=%AppData%\Microsoft\Excel\XLSTART"

if not exist "%TARGET%" (
    echo Khong tim thay thu muc: %TARGET%
    pause
    exit /b
)

echo =====================================
echo CHUONG TRINH XOA VIRUS EXCEL
echo =====================================
echo Thu muc: %TARGET%
echo.

:: Count files
set total=0
for %%F in ("%TARGET%\*") do (
    set /a total+=1
)

if %total%==0 (
    echo Khong co tep nao trong thu muc de xoa.
    echo Bam bat ky phim nao de thoat.
    pause
    exit /b
)

echo Tong so tep phat hien: %total%
echo.

:: Tien trinh xoa tep
set count=0
set "has_deleted="

for %%F in ("%TARGET%\*") do (
    set /a count+=1
    echo [!count!/%total%] Dang xoa: %%~nxF
    del /f /q "%%F"
    
    :: Kiem tra neu tep da thuc su bi xoa de danh dau
    if not exist "%%F" (
        set "has_deleted=true"
    )
)

echo.
echo Da hoan thanh qua trinh xoa!
echo.

if "%has_deleted%"=="true" (
    goto :ASK_REBOOT
) else (
    echo Khong co tep nao bi xoa. Bam bat ky phim nao de thoat.
    pause
    exit /b
)

:ASK_REBOOT
echo =====================================
echo Da xoa virus!. Ban can khoi dong lai may tinh...
echo [Y] Co, khoi dong lai ngay.
echo [N] Khong, chi thoat chuong trinh.
echo =====================================
choice /c YN /n /m "Nhap lua chon cua ban (Y/N): "

if errorlevel 2 (
    echo.
    echo Cam on ban da su dung. Dang thoat...
    timeout /t 3 >nul
    exit /b
)

if errorlevel 1 (
    echo.
    echo May tinh se khoi dong lai trong 3 giay. Vui long luu lai cong viec!
    shutdown /r /t 3 /c "May tinh dang khoi dong lai sau khi quet virus Excel."
    exit /b
)